Un contatore di accessi grafico in ASP

ASP E-Commerce con ASP Menu Javascript Area Aziende Cocktail Registrazione domini

Home + Articoli + Contatori e Statistiche + Articolo # 105

Concesso in esclusiva a Mr.Webmaster. Vietata la riproduzione.

In più di un esempio abbiamo visto come realizzare un contatore di accessi, unici o meno, in ASP, memorizzando il numero di accessi su un file di testo utilizzando il File System Object, in un database o in un file XML. L'esempio proposto in questo articolo vede la realizzazione di un contatore di accessi su file di testo ma al posto di visualizzare il numero in formato testo, utilizzeremo delle immagini per renderlo maggiormente accattivante.

Per prima cosa create delle immagini i piccole dimensioni, ad esempio 20 X 20 pixel, ognuna delle quali deve riportare un numero, da 0 a 9.

Creerete quindi i file

0.gif
1.gif
2.gif
3.gif
4.gif
5.gif
6.gif
7.gif
8.gif
9.gif

ognuno dei quali riporterà il numero di cui al nome del file; disponeteli nella cartella di prova all'interno del vostro server Web personale, ricordando di settare i permessi sia in lettura che in scrittura.

Create poi il file contatore.txt il cui valore di default, da impostare a mano, dev'essere zero

Segue il codice ASP abbondantemente commentato, del contatore

<%@LANGUAGE = VBScript%>
<html>
<body>

<p align="center">
<%
' Dichiaro le variabili che mi servono
Dim file, fso, conta, accessi, scrivi, i

' Recupero il file di testo in cui salvare il numero di accessi
file = Server.MapPath("contatore.txt")

' Dichiaro l'oggetto File System
Set fso = Server.CreateObject("Scripting.FileSystemObject")

' Apro il file di tsto
Set conta = fso.OpenTextFile(file, 1, True)

' Verifico il contenuto del file di testo
If conta.AtEndOfStream = False Then
    accessi = CLng(conta.ReadAll())
Else
    accessi = 0
End If

' Un po di pulizia...
Set conta = Nothing

' Incremento il numero di accessi
accessi = accessi + 1

' Scrivo il risultato aggiornato nel file di testo
Set scrivi = fso.CreateTextFile(file, True)
scrivi.WriteLine accessi
Set scrivi = Nothing

' Un po di pulizia...
Set fso = Nothing

' Stampo a video il contatore e le relative immagini
For i = 1 To Len(accessi)
    Response.Write "<img src=""" & Mid(accessi, i, 1) & ".gif"">"
Next
%>
</p>

</body>
</html>

Lascio al lettore il compito di rendere unico il contatore utilizzando i cookie.