Abbiamo precedentemente visto come stampare a video il numero di utenti connessi con ASP. Vediamo adesso come recuperare i nomi degli utenti connessi al nostro sito, ovvero le username.

Vediamo come.

Iniziamo col corredare il file Global.asa col seguente codice:

<script language="VBScript" runat="server">
    Sub Application_OnStart
        Application("nomi") = ""
    End Sub
    Sub Session_OnEnd
        Dim n
        n = Replace(Application("nomi") , Session("nome") & "|" ,"")
        Application.Lock
        Application("nomi") = n
        Application.UnLock
    End Sub
</script>

Passiamo alla pagina di login; una volta creata la sessione, ovvero nel caso in cui la procedura di autenticazione sia andata a buon fine, aggiungiamo queste poche righe di codice ASP al codice della pagina di login stessa:

If InStr(1, Application("nomi"), Session("nome") & "|" ) = 0 Then
    Application.Lock
    Application("nomi") = Application("nomi") & Session("nome") & "|"
    Application.UnLock
End If

Si abbia però cura di chiamare Session(“nomi”) la variabile di sessione creata all’atto dell’autenticazione, oppure cambiare in Session(“username”) le variabili di sessione dell’esempio di questo articolo, a seconda di come si preferisce.

Passiamo alla fase di stampa a video dei nomi degli utenti connessi al proprio sito:

<p>
<b>Utenti connessi:</b><br><br>
<%
    Dim nomi, i
    nomi = Split(Application("nomi"), "|")
    i = 0
    For i = 0 To UBound(nomi)
        Response.Write nomi(i) & " - "
    Next
%>
</p>

Recuperiamo le variabili di ambiente, le filtriamo con un array di stringa ed effettuiamo un ciclo per stampare a video i singoli risultati.